Imports System.Net
Imports System.Net.Sockets

''' <summary>
''' Demo of a TCP server, listening on a configurable IPv4 port and address for remote
''' connections from an allowed remote IP address, and controlling a fischertechnik
''' motor using a Robo Interface.
''' </summary>
''' <remarks>WARNING: This is by no means production-ready code but just intended to
''' demonstrate one principal possibility to tackle the problem. Use this code at your
''' own risk.</remarks>
Public Module Main

    Public Sub Main()

        Const Motor = FishFace40.Out.M1

        Console.WriteLine("Opening Robo Interface with serial number {0}", My.Settings.RoboInterfaceSerialNumber)

        Dim roboInterface As New FishFace40.FishFace

        roboInterface.OpenInterface(My.Settings.RoboInterfaceSerialNumber)
        Try

            Dim allowedRemoteIP = IPAddress.Parse(My.Settings.AllowedRemoteIP)

            Dim listener As New TcpListener(IPAddress.Parse(My.Settings.ListenerAddress),
                                            My.Settings.ListenerPort)

            listener.Start()
            Try
                Do
                    Console.WriteLine("Waiting for connection (blocking)")
                    ' TODO: Use non-blocking calls.
                    Using client = listener.AcceptTcpClient

                        Dim remoteAddress = DirectCast(client.Client.RemoteEndPoint, IPEndPoint).Address

                        Console.WriteLine("Connection attempt from remote address {0}", remoteAddress)

                        If remoteAddress.Equals(allowedRemoteIP) Then
                            Console.WriteLine("Remote address is valid, waiting for commands")
                            ' TODO: Ensure that the remote client is trusted.
                            ' TODO: Use encrypted and possibly digitally signed traffic.
                            ' TODO: Authentificate the client using some credentials.
                            Using stream = client.GetStream
                                Using reader As New IO.StreamReader(stream)
                                    Do
                                        Select Case reader.ReadLine.ToUpperInvariant
                                            Case "ON"
                                                roboInterface.SetMotor(Motor, FishFace40.Dir.Rechts)
                                            Case "OFF"
                                                roboInterface.SetMotor(Motor, FishFace40.Dir.Off)
                                            Case Else
                                                Console.WriteLine("Unknown command; terminating connection.")
                                                Exit Do
                                        End Select
                                    Loop
                                End Using
                            End Using
                        Else
                            Console.WriteLine("This remote address is not allowed.")
                        End If
                    End Using
                Loop
            Finally
                listener.Stop()
            End Try
        Finally
            Console.WriteLine("Closing Robo Interface")
            roboInterface.CloseInterface()
        End Try
    End Sub

End Module

Imports System.Net
Imports System.Net.Sockets

''' <summary>
''' Demo of a TCP client, listening to a fischertechnik switch on a Robo Interface and
''' sending the state changes as commands to a remote server.
''' </summary>
''' <remarks>WARNING: This is by no means production-ready code but just intended to
''' demonstrate one principal possibility to tackle the problem. Use this code at your
''' own risk.</remarks>
Public Module Main

    Public Sub Main()

        Const Switch = FishFace40.Inp.I1

        Console.WriteLine("Opening Robo Interface with serial number {0}",
                          My.Settings.RoboInterfaceSerialNumber)

        Dim roboInterface As New FishFace40.FishFace

        ' Using Robo Interface on COM1:
        roboInterface.OpenInterface(FishFace40.IFTypen.ftROBO_IF_COM, FishFace40.Port.COM1, 100)
        ' Using Robo Interface on USB:
        'roboInterface.OpenInterface(My.Settings.RoboInterfaceSerialNumber)
        Try
            Dim remoteIPAddress = IPAddress.Parse(My.Settings.RemoteIPAddress)

            Console.WriteLine("Connecting to remote server at IP address {0} on port {1}",
                              remoteIPAddress, My.Settings.RemotePort)

            Using client = New TcpClient
                ' TODO: Ensure that the remote server is trusted.
                client.Connect(remoteIPAddress, My.Settings.RemotePort)
                Using writer As New IO.StreamWriter(client.GetStream)
                    ' TODO: Use encrypted and possibly digitally signed traffic.
                    ' TODO: Authenticate with the server.
                    Console.WriteLine("Observing switch, press any key to stop.")
                    Do Until Console.KeyAvailable
                        roboInterface.WaitForChange(Switch, 1)
                        If roboInterface.GetInput(Switch) Then
                            Console.WriteLine("Sending ON")
                            writer.WriteLine("ON")
                        Else
                            Console.WriteLine("Sending OFF")
                            writer.WriteLine("OFF")
                        End If
                        writer.Flush()
                    Loop
                    Console.WriteLine()
                    Console.WriteLine("Disconnecting")
                    writer.WriteLine("QUIT") ' Invalid command for the server, causing it to terminate.
                End Using
            End Using
        Finally
            Console.WriteLine("Closing Robo Interface")
            roboInterface.CloseInterface()
        End Try

    End Sub

End Module